Case 2
    AutoTalk
      0;データ生成中……
    Suspend

    Set ソート情報あり 1
    Load !挑戦者
    Call パーティキャラ読み込み
    Call 作品タイプ別順ソート用
	Set ソートタイプ[1] "なし"
    SortType = "クラス 名称 最大ＨＰ 最大ＥＮ 装甲 運動性 移動力 最大攻撃力 最大射程 " _
    	& "最大ＳＰ 格闘 射撃 命中 回避 技量 反応"
	For i = 1 To LLength(SortType)
		Set ソートタイプ[i + 1] LIndex(SortType, i)
	Next
	Set ソートタイプ[1000] "キャンセル"

    Set ソート "なし"
    Set ソート順 ""

    Set 残り パーティ人数

    Set temp[-1] ("―― ソート[" & ソート & "] ――")
    Set temp[0] ("残り" & Wide(残り) & "人をランダムに決める")
    For i = 1 to キャラ数
        Set temp[i] ("    " & キャラ[i])
    Next

    AutoTalk
      0;データ生成中……
    End

    Do while 1
      Set temp[0] ("残り" & Wide(残り) & "人をランダムに決める")
      Set temp[1000] temp[0]
      Ask temp "キャラクターを $(パーティ人数) 人選んで下さい(あと $(残り) 人)" 拡大 連続表示
      If (選択 = 0) or (選択 = 1000) Then
          For j = (パーティ人数 - 残り + 1) to パーティ人数
            Set C_N[j] Random(キャラ数)
            Do while 1
              If 済み[C_N[j]] = 0 Then
                Set 済み[C_N[j]] 1
                Set 選択済み[C_N[j]] キャラ[C_N[j]]
                Set 生成予定[j] C_N[j]
                Break
              Endif
              If C_N[j] = キャラ数 Then
                Set C_N[j]
              Else
                Incr C_N[j]
              Endif
            Loop
          Next
          Set 残り 0
      ElseIf 選択 = -1 Then
      // ソート処理
        Ask ソートタイプ "ソートの種類を選択してください" 拡大 キャンセル可 連続表示
        If (選択 = 0) or (選択 = 1000) Then
          Skip
        EndIf
        Set buf ソートタイプ[選択]

        If (buf = "なし") And (ソート != "なし") Then
        // ソートなしの場合の処理
          UnSet temp
          Set ソート "なし"
          Set ソート順 ""
          Set temp[-1] ("―― ソート[" & ソート & "] ――")
          Set temp[0] ("残り" & Wide(残り) & "人をランダムに決める")
          For i = 1 to キャラ数
            If 済み[i] Then
              Set temp[i] (" ○ " & キャラ[i])
            Else
              Set temp[i] ("    " & キャラ[i])
            EndIf
          Next
        ElseIf buf != "なし" Then
        // ソートする場合、ソート順を選択
          Ask "ソート順を選択してください" 拡大 キャンセル可
            昇順
            降順
            キャンセル
          End
          If 選択 = 1 Then
            Set buf2 "昇順"
          ElseIf 選択 = 2 Then
            Set buf2 "降順"
          Else
            Skip
          EndIf

          If (ソート != buf) Or (ソート順 != buf2) Then
          // 前回とソートの種類・順番が違う場合のみ処理
            AutoTalk
              0;ソート中……
            Suspend

            Set ソート buf
            Set ソート順 buf2

            UnSet temp
            UnSet temp2
            Set temp[-1] ("―― ソート[" & buf & ":" & buf2 & "] ――")
            Set temp[0] ("残り" & Wide(残り) & "人をランダムに決める")

			If AppVersion >= 20106 Then
				// SRC Ver2.1.6以降では本体のSortコマンドを使用
	            For i = 1 to キャラ数
	                Set temp2[i] ソート用[buf, i]
	            Next

				If (buf = "クラス") Or (buf = "名称") Then
					Sort temp2 buf2 文字 文字インデックス
				Else
					Sort temp2 buf2 数値 文字インデックス
				EndIf

				ForEach i In temp2
	              If 済み[i] Then
	                Set temp[i] (" ○ " & キャラ[i] & "  " & temp2[i])
	              Else
	                Set temp[i] ("    " & キャラ[i] & "  " & temp2[i])
	              EndIf
	            Next
	        Else
				// Sortコマンドがない場合は自前でソート
	            For i = 1 to キャラ数
	                Set temp2[i] i
	            Next

	            For i = 1 To (キャラ数 - 1)
	              For j = i To キャラ数
	                If (buf = "クラス") Or (buf = "名称") Then
	                    // 文字列のソート
		                If buf2 = 昇順 Then
		                  If StrComp(ソート用[buf, temp2[i]], ソート用[buf, temp2[j]]) = 1 Then
		                    Set k temp2[i]
		                    Set temp2[i] temp2[j]
		                    Set temp2[j] k
		                  EndIf
		                Else
		                  If StrComp(ソート用[buf, temp2[i]], ソート用[buf, temp2[j]]) = -1 Then
		                    Set k temp2[i]
		                    Set temp2[i] temp2[j]
		                    Set temp2[j] k
		                  EndIf
		                EndIf
		            Else
		                // 数値のソート
		                If buf2 = 昇順 Then
		                  If ソート用[buf, temp2[i]] > ソート用[buf, temp2[j]] Then
		                    Set k temp2[i]
		                    Set temp2[i] temp2[j]
		                    Set temp2[j] k
		                  EndIf
		                Else
		                  If ソート用[buf, temp2[i]] < ソート用[buf, temp2[j]] Then
		                    Set k temp2[i]
		                    Set temp2[i] temp2[j]
		                    Set temp2[j] k
		                  EndIf
		                EndIf
		            EndIf
	                Wait 0
	              Next
	            Next

	            For i = 1 To キャラ数
	              If 済み[temp2[i]] Then
	                Set temp[temp2[i]] (" ○ " & キャラ[temp2[i]] & "  " & ソート用[buf, temp2[i]])
	              Else
	                Set temp[temp2[i]] ("    " & キャラ[temp2[i]] & "  " & ソート用[buf, temp2[i]])
	              EndIf
	            Next
	        EndIf

            AutoTalk
              0;ソート中……
            End
          EndIf
        EndIf
        UnSet temp2
      Else
        Set temp2 キャラ[選択]
        If 選択済み[選択] = "" Then
          Set 済み[選択] 1
          Set 選択済み[選択] temp2
          Set temp[選択] (" ○ " & Right(temp[選択], Len(temp[選択]) - 4))
          Set 番号 (11 - 残り)
          Set 生成予定[番号] 選択
          Incr 残り -1
        Else
          UnSet 済み[選択]
          Unset 選択済み[選択]
          Set temp[選択] ("    " & Right(temp[選択], Len(temp[選択]) - 3))
          Incr 残り 1
        Endif
      Endif
      If 残り = 0 Then
        Set 選択済み[999] 選択キャラを入れ替える
        Ask 選択済み "この10人でよろしいですか？(キャンセルなら右クリック)" 拡大 キャンセル可 連続表示
        If 選択 = 999 Then
          Unset 選択済み[999]
          Do while 1
            Ask 選択済み "入れ替えるキャラを選んで下さい？(このままでいいなら右クリック)" 拡大 キャンセル可 連続表示
             If 選択 = "" Then
              Break
            Else
              Set 変えられる人 キャラ[選択]
              For i = 1 to キャラ数
                Set change[i] キャラ[i]
              Next
              ForEach tmp In 選択済み
                Unset change[tmp]
              Next
              Set CCN 選択
              Ask change "$(変えられる人) と入れ替えるキャラを選んで下さい" 拡大 キャンセル可 連続表示
              If 選択 <> "" Then
                Set 選択済み[選択] キャラ[選択]
                Unset 選択済み[CCN]
              Endif
              Unset change
            Endif
          Loop
          Break
        ElseIf 選択 <> "" Then
          Unset 選択済み[999]
          Break
        Else
          Set 残り パーティ人数
          Unset 済み
          Unset temp
          Unset 選択済み
          Set temp[0] ("残り" & Wide(残り) & "人をランダムに決める")
          For i = 1 to キャラ数
            Set temp[i] ("   " & キャラ[i])
          Next
        Endif
      Endif
    Loop
    AutoTalk
    0.1;読み込み中……
    Suspend
    If Dir("Data\!ローカル追加用",フォルダ) <> "" Then
      Load !挑戦者 !ローカル追加用
    Else
      Load !挑戦者
    Endif
    Talk
    End
    ForEach tmp In 選択済み
      Call キャラ生成 選択済み[tmp]
    Next
    ForEach 味方 全て
      Call 合体形態作成 Pilot()
    Next
    Call 戦闘データ変数初期化
